// Capteur de confinement 
 // temps , Temperature , CO2 , humidité 
 // Enregistrement sur carte SD
 #include <LSD.h>
 #include <LBattery.h>
 
 //Capteur de co2
 const unsigned char cmd_get_sensor[] = { 0xff, 0x01, 0x86, 0x00, 0x00, 0x00, 0x00, 0x00, 0x79 };
 unsigned char dataRevice[9];
 int temperature;
 int CO2PPM;
 
 //Capteur d'humidité et temperature 
 #include "DHT.h"
 #define DHTPIN 2 // what pin we're connected to
 #define DHTTYPE DHT22   // DHT 22  (AM2302)
 DHT dht(DHTPIN, DHTTYPE);
 float tDHT;
 float hDHT;
 
 // Ecran LCD
 #include <Wire.h>
 #include "rgb_lcd.h"
 rgb_lcd lcd;
 const int switchLCDPin = 3;
 int switchState = 0; // variable pour lire l'état de l'interupteur 
 // Caracteres spéciaux pour afficher le niveau de battrie sur l'écran LCD
 
 
 void setup() {
   dht.begin();  // initialise le capteur d'humidité 
   Serial1.begin(9600); //démarre la communication avec le capteur de CO2
   
   //Ouvre le port serie
   Serial.begin(115200);
   Serial.print("Initialisation de la carte SD...");
   LSD.begin();
   Serial.println("carte initialisée.");
   
   //Quelques infos 
   Serial.println(" 350~450 ppm : Environnement exterieur");
   Serial.println(" 350~1000 ppm : L'air est frais");
   Serial.println(" 1000~2000 ppm : L'air est stagnante et vous vous sentez fatigue");
   Serial.println(" 2000~5000 ppm : Maux de tete, sommeil, incapable de vous concentrer et meme une legere nausee");
   Serial.println(" >5000 ppm : grave epuisement de l'oxygene, des lesions cerebrales permanentes et meme la mort");
   
   pinMode(switchLCDPin, INPUT);  // configuration de l'interrupteur 
   switchState = digitalRead(switchLCDPin); // Lecture de l'état de l'interupteur
   lcd.begin(16, 2); // Initialisation de l'écran LCD
   if (switchState){ // Si le bouton est sur On
     lcd.display(); //Démarage de l'affichage
     lcd.setRGB(5,5,5); //définition des couleurs du rétro-éclairage
     lcd.createChar(0, bat100); //Enregistrement du caractere pour afficher le niveau de battrie a 100%
     lcd.createChar(1, bat66); //Enregistrement du caractere pour afficher le niveau de battrie a 66%
     lcd.createChar(2, bat33); //Enregistrement du caractere pour afficher le niveau de battrie a 33%
     lcd.createChar(3, bat0);  //Enregistrement du caractere pour afficher le niveau de battrie a 0%
   } else { // Sinon
     lcd.noDisplay(); // on éteind l'écran   
   }
 }
 
 void loop() {
     String dataString = "";  // Déclaration d'une chaine de caractere pour stoquer les données:
     int ret = dht.readHT(&tDHT,&hDHT); // lecture de la temperature de l'humidité
     if(dataRecieve() && hDHT > 0 ) //Si on a recus des donnée du capteur de CO2 et d'humidité
     {      
         //Création de la chaine de caractere avec toutes les infos des capteurs
         dataString += millis()/1000;
         dataString += ",";
         //dataString += String(temperature);
         //dataString += ",";
         dataString += String(CO2PPM);
         dataString += ",";
         dataString += String(tDHT);
         dataString += ",";
         dataString += String(hDHT);
         
         info(dataString); // Appel de la fonction qui gere l'affichage sur le LCD     
         
         LFile dataFile = LSD.open("CO2.txt", FILE_WRITE); // ouverture du fichier CO2
         // Si le fichier est ouvert on ecris les données 
         if (dataFile) {
             dataFile.println(dataString); // Ajout dans le fichier de la chaine de caractere dataString
             dataFile.close(); //Fermeture du fichier
         } else {
             Serial.println("erreur d'ouverture du fichier CO2.txt");
         }
     }
     delay(2000); // On attend 2 secondes
 }
 
 bool dataRecieve(void)
 {
     byte data[9];
     int i = 0;
     //transmt command data
     for(i=0; i<sizeof(cmd_get_sensor); i++) 
     {
         Serial1.write(cmd_get_sensor[i]);
     }
     delay(10);
     //begin reveiceing data
     if(Serial1.available())
     {
         while(Serial1.available())
         {
             for(int i=0;i<9; i++) { data[i] = Serial1.read(); }
         }
     } 
     if((i != 9) || (1 + (0xFF ^ (byte)(data[1] + data[2] + data[3]
     + data[4] + data[5] + data[6] + data[7]))) != data[8])
     {
         return false;
     }
     CO2PPM = (int)data[2] * 256 + (int)data[3];
     temperature = (int)data[4] - 40;
  
     return true;
 }
 
 void info(String data)
 {
   switchState = digitalRead(switchLCDPin);
   if (switchState){
     lcd.display(); 
     lcd.setRGB(map(CO2PPM,350,5000,0,100),5,map(CO2PPM,350,5000,20,5));
     lcd.clear();
     lcd.print("CO2:");
     lcd.setCursor(4,0);
     lcd.print(CO2PPM);       
     lcd.setCursor(0,1);
     lcd.print("T:");        
     lcd.setCursor(2,1);        
     lcd.print(tDHT);
     lcd.setCursor(9,1);
     lcd.print("H:");        
     lcd.setCursor(11,1);        
     lcd.print(hDHT);
     lcd.setCursor(10,0);
     char buffer[16];
     sprintf(buffer, "%02d:%02d", millis()/1000/60 , (millis()/1000)%60);
     lcd.print(buffer);
     lcd.setCursor(15,0);
     switch (LBattery.level()) {
       case 100:
         lcd.write((unsigned char)0);
         break;
       case 66:
         lcd.write((unsigned char)1);
         break;
       case 33:
         lcd.write((unsigned char)2);
         break;
       default:
         lcd.write((unsigned char)3);
       break;
     }
   } else {
     lcd.setRGB(0,0,0);
     lcd.noDisplay();
     Serial.println(data);
   }
 }